Send logs from Zig

The opentelemetry-sdk for Zig is in alpha (v0.1.1). Expect breaking changes between releases.

Send Zig logs to Rootprint through the OpenTelemetry SDK’s std.log bridge, which routes existing std.log calls over OTLP HTTP.

Prerequisites

A running Rootprint instance. Substitute its host for <your-rootprint>.
Zig ≥ 0.15.2.
An ingest API key scoped to an OpenTelemetry logs index such as otel-logs-v0_9. In Settings → API keys, click Create ingest key and pick the index. See API keys.

Setup

Add the SDK to your project

Run this in your project root:

zig fetch --save "git+https://github.com/zig-o11y/opentelemetry-sdk#v0.1.1"

Then add these lines to build.zig after your exe declaration:

const otel_sdk = b.dependency("opentelemetry", .{
    .target = target,
    .optimize = optimize,
});
exe.root_module.addImport("opentelemetry-sdk", otel_sdk.module("sdk"));

Minimal working example

SDK v0.1.1 doesn’t read the auth header from the environment, so the example sets the endpoint, header, and service name in code. Replace <your-rootprint> and <your-ingest-api-key>. Leave the OTEL_EXPORTER_OTLP_* endpoint variables unset: they override the endpoint set in code.

Show src/main.zig

const std = @import("std");
const sdk = @import("opentelemetry-sdk");

pub const std_options: std.Options = .{
    .logFn = sdk.logs.std_log_bridge.logFn,
};

pub fn main() !void {
    var gpa = std.heap.GeneralPurposeAllocator(.{}){};
    defer _ = gpa.deinit();
    const allocator = gpa.allocator();

    var otlp_config = try sdk.otlp.ConfigOptions.init(allocator);
    defer otlp_config.deinit();
    otlp_config.endpoint = "<your-rootprint>";
    otlp_config.scheme = .https;
    otlp_config.headers = "Authorization=Bearer <your-ingest-api-key>";

    var otlp_exporter = try sdk.logs.OTLPExporter.init(allocator, otlp_config);
    defer otlp_exporter.deinit();
    const exporter = otlp_exporter.asLogRecordExporter();

    var simple_processor = sdk.logs.SimpleLogRecordProcessor.init(allocator, exporter);
    const processor = simple_processor.asLogRecordProcessor();

    const service_name: []const u8 = "my-zig-service";
    const resource = try sdk.attributes.Attributes.from(allocator, .{ "service.name", service_name });
    defer if (resource) |attrs| allocator.free(attrs);

    var provider = try sdk.logs.LoggerProvider.init(allocator, resource);
    defer provider.deinit();
    try provider.addLogRecordProcessor(processor);

    try sdk.logs.std_log_bridge.configure(.{
        .provider = provider,
        .also_log_to_stderr = true,
    });
    defer sdk.logs.std_log_bridge.shutdown();

    std.log.info("Hello from Zig to Rootprint", .{});

    try provider.shutdown();
}

Save as src/main.zig and run zig build run.

Verify in Rootprint

Open Logs, filter on service_name:my-zig-service, and your record should appear within a few seconds.

Log levels and attributes

The std.log bridge maps Zig log levels to OpenTelemetry log levels:

Zig level	Log level (`severity_number`)
`debug`	DEBUG (5)
`info`	INFO (9)
`warn`	WARN (13)
`err`	ERROR (17)

std.log has no key/value attributes. Format arguments are interpolated into the message, which becomes the log record body:

std.log.info("user signed up: {s} plan={s}", .{ user_id, plan });

For attributes, use the SDK’s logger API directly. See the examples/logs/ folder in the SDK repository.

Troubleshooting

The program hangs and prints Deadlock detected: an export failed, for example with a 401 from a wrong ingest API key. SDK v0.1.1 deadlocks when it logs the failure through the std.log bridge. Check the endpoint and key in otlp_config. See Response codes.
200 but no records in Logs: the ingest API key is scoped to an index without the OpenTelemetry logs schema, so the records are discarded. See Index target.

Get Started

Send Logs

Traces

Search Logs

Manage Rootprint

Send logs from Zig

Prerequisites

Setup

Log levels and attributes

Troubleshooting

​Prerequisites

​Setup

​Log levels and attributes

​Troubleshooting

​Related

Prerequisites

Setup

Log levels and attributes

Troubleshooting

Related